蓝点网
给你感兴趣的内容!

科普:删除“这台电脑”主界面及侧边的六个文件夹

老话题了,有强迫症的网友伤不起!经常有网友问这个,所以还是手滑写出来一个,这样不用每次手打了,噢耶!其实就是通过删除注册表来干掉他们,这次一起顺便把侧边的也干掉!

正常的样子:

thispcimg1

去除后的样子:img2

步骤:下载附件或者自己手动复制代码

1.管理员模式运行。

huiche

2.随你删除哪些,输入对应数字后回车

3.想恢复了再次运行可恢复

4.附件下载地址:http://pan.baidu.com/s/1ms7EX

代码如下,有兴趣可以自己弄

1.//新建文本文档一个,打开,复制以下代码进去保存//
@echo off
title win8.1碍眼文件夹处理
mode con cols=47 lines=16
setlocal enabledelayedexpansion
tasklist /fi "windowtitle eq win8.1碍眼文件夹处理"|find "cmd.exe" > nul
if %errorlevel% == 0 (
echo ==============================================
echo ===== =====
echo ===== !请右键以管理员身份运行! =====
echo ===== =====
echo ==============================================
pause > nul
exit
)
set x86=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\
systeminfo 2> nul|find "x64" > nul
if %errorlevel%==0 (
set x64=HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\
) else (
set x64=%x86%
)
set videos={A0953C92-50DC-43bf-BE83-3742FED03C9C}
set pictures={3ADD1653-EB32-4cb0-BBD7-DFA0ABB5ACCA}
set documents={A8CDFF1C-4878-43be-B5FD-F8091C1C60D0}
set downloads={374DE290-123F-4565-9164-39C4925E467B}
set music={1CF1260C-4DD0-4ebb-811F-33C572699FDE}
set desktop={B4BFCC3A-DB2C-424C-B029-7FE99A87C641}
:begin
cls
echo ==============================================
echo ===== win8.1碍眼文件夹处理 =====
echo ===== =====
echo ===== 1删除 2还原 0退出 =====
echo ==============================================
set m=3
set /p m=请选择(选择后别忘了按回车,蓝点网http://www.landiannews.com/):
if %m%==0 exit
if %m%==1 set ad=delete&&set ch=删除&&goto ch
if %m%==2 set ad=add&&set ch=还原&&goto ch
goto begin
:ch
cls
echo ==============================================
echo ===== 请选择%ch%的项目 1视频 2图片 =====
echo ===== 3文档 4下载 5音乐 6桌面 =====
echo ===== 7全部 0返回主菜单 =====
echo ==============================================
echo 请选择(选择多个时,请用空格隔开):
set n=
set all=
set /p n=
for %%i in (%n%) do (
if %%i==0 goto begin
if %%i==1 set all=!all!%videos% 
if %%i==2 set all=!all!%pictures% 
if %%i==3 set all=!all!%documents% 
if %%i==4 set all=!all!%downloads% 
if %%i==5 set all=!all!%music% 
if %%i==6 set all=!all!%desktop% 
if %%i==7 set all=!all!%videos% %pictures% %documents% %downloads% %music% %desktop% 
)
echo %all%|find "-" >nul
if %errorlevel%==0 (
for %%i in (%all%) do (
reg %ad% %x86%%%i /f
reg %ad% %x64%%%i /f
) > nul 2> nul
) else (
goto ch
)
echo %ch%完成,按任意键返回
pause > nul
goto ch


将以上代码复制进txt保存,将.txt改为.cmd ,然后右键管理员模式运行即可
转载请注明来源于蓝点网及本文链接:蓝点网 » 科普:删除“这台电脑”主界面及侧边的六个文件夹
分享到:更多 ()
以下评论内容由网友保留所有权,除非特别注明否则所有评论均不代表本站观点!

评论 6

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址
  1. #3

    连接挂了

    三鲜哥3年前 (2014-06-11)回复
  2. #2

    额?我测试使用正常啊

    山外的鸭子哥3年前 (2014-02-27)回复
  3. #1

    这个脚本选择过 删除还是恢复 什么的 直接闪现下一个窗口 然后消失 请问博主怎么解决

    陪你看日落3年前 (2014-02-25)回复
    • 额?没懂

      山外的鸭子哥3年前 (2014-02-26)回复
      • Google Chrome 33.0.1750.117 Google Chrome 33.0.1750.117 Windows 8.1 x64 Edition Windows 8.1 x64 Edition

        第一步 是选择删除还是恢复什么的 我选择了删除 然后出现下一步选择删除哪些,但是第二步这个窗口一闪而过 没法选

        test3年前 (2014-02-27)回复